***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 16, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD15P06A-AU   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -1.9		 kp = 9.2		)
.model  dds   d(
+   is = 5.037e-11	  n = 1.189		   rs = 1.308e-2
+   eg = 1.012	       trs1 = 1.045e-2)
.model  dbody d(
+   is = 5.037e-11	  n = 1.189		   rs = 1.308e-2
+  cjo = 1.505e-10	  m = 3.394e-1		   vj = 8.242e-1
+   bv = 66		ibv = 250e-6		 tbv1 = 4.488e-4		tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 3.265e-10	  m = 5.974e-1		   vj = 1.248e-0)
.param
+  cgs = 1.121e-9	cgd = 3.156e-10
+   rd = 1.131e-2	 ra = 1.131e-2		  trd = 2.041e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (2.00 , 2.00 ),
+ (3.00 , 3.02 ),
+ (3.10 , 3.12 ),
+ (3.50 , 3.49 ),
+ (4.00 , 3.90 ),
+ (4.50 , 4.18 ),
+ (5.00 , 4.42 ),
+ (5.50 , 4.58 ),
+ (6.00 , 4.70 ),
+ (7.00 , 4.86 ),
+ (8.00 , 4.98 ),
+ (10.0 , 5.18 ),
+ (20.0 , 5.40 ),
+ (22.0 , 5.40 ))
egt	  1  2t   value = {6.207e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
